Piloter la LED RGB de la carte depuis un tableau de bord

// Climate sensor + RGB light: AM2301 (DHT21) and the on-board WS2812 LED
// of a Waveshare ESP32-C6-Zero.
// WiFi, device token and encryption key are injected by PneX at build time.
#include <Pnex.h>
#include <DHT.h>

#define DHT_PIN 0        // GP0, yellow wire
#define DHT_TYPE DHT21   // AM2301 = DHT21
#define RGB_PIN 8        // on-board WS2812 LED (do not use GPIO8 for anything else)

PnexDevice pnex;
DHT dht(DHT_PIN, DHT_TYPE);

// Light state, changed by the commands, applied in loop().
bool light_on = false;
int light_level = 100;             // brightness, 0..100 %
uint32_t light_color = 0xFFFFFF;   // 0xRRGGBB
bool light_dirty = true;

// Commands sent by the flow's "Device (write)" node: the wired value is
// in args["value"]. Keep handlers short: store, then apply in loop().
bool on_power(JsonVariantConst args) {
    light_on = args["value"].as<int>() != 0;
    light_dirty = true;
    return true;
}

bool on_level(JsonVariantConst args) {
    light_level = constrain(args["value"].as<int>(), 0, 100);
    light_dirty = true;
    return true;
}

bool on_color(JsonVariantConst args) {
    light_color = args["value"].as<uint32_t>() & 0xFFFFFF;
    light_dirty = true;
    return true;
}

void apply_light() {
    uint8_t r = 0, g = 0, b = 0;
    if (light_on) {
        r = ((light_color >> 16) & 0xFF) * light_level / 100;
        g = ((light_color >> 8) & 0xFF) * light_level / 100;
        b = (light_color & 0xFF) * light_level / 100;
    }
    // The C6-Zero's LED takes red, green, blue in that order (not GRB).
    rgbLedWriteOrdered(RGB_PIN, LED_COLOR_ORDER_RGB, r, g, b);
    pnex.publish("light", light_on ? 1 : 0);  // actual state, for the card
}

void setup() {
    Serial.begin(115200);
    dht.begin();

    // Each metric becomes a telemetry series of this device.
    pnex.addMetric("temperature", "°C");
    pnex.addMetric("humidity", "%");
    pnex.addMetric("light");

    // Each command shows up in the flow's "Device (write)" node.
    pnex.onCommand("power", on_power);
    pnex.onCommand("level", on_level);
    pnex.onCommand("color", on_color);

    pnex.begin();  // WiFi + connection to your PneX server
}

unsigned long last_read_ms = 0;

void loop() {
    pnex.loop();  // call it on every iteration, never block with long delays

    if (light_dirty) {
        light_dirty = false;
        apply_light();
    }

    // The AM2301 needs at least 2 s between two reads: read every 10 s.
    if (millis() - last_read_ms >= 10000) {
        last_read_ms = millis();
        pnex.publish("light", light_on ? 1 : 0);
        float t = dht.readTemperature();
        float h = dht.readHumidity();
        if (isnan(t) || isnan(h)) {
            Serial.println("[APP] AM2301 read failed (check wiring)");
            return;
        }
        pnex.publish("temperature", t);
        pnex.publish("humidity", h);
        Serial.printf("[APP] %.1f °C  %.1f %%\n", t, h);
    }
}